Demo entry 5205659

Plots of Sr-90 activity in Techa River

   

Submitted by physicist on Jun 09, 2016 at 07:59
Language: Gnuplot. Code size: 3.4 kB.

##### Start of GNUPLOT header #####
set print "-"
print ''
print '-  < << <<<        _.:GNUPLOTTING:._        >>> >> >  - '


set term png truecolor size 1200,800 font 'ubuntu mono,14'
system 'mkdir -p plot'

set autoscale
set grid

filename = 'plot/Sr-'
SR_DISTANCE_MEAS = 'MEAS_SR_DIST.txt'
SR_TIMELINE_MEAS = 'MEAS_SR_TIME.txt'

SR_DISTANCE_CALC = 'CC_DIST_'.COMP_NUM.'_'.BED_TYPE.'-1996.txt'
SR_TIMELINE_CALC = 'CC_TIME_'.COMP_NUM.'_'.BED_TYPE.'-1996.txt'

set key right top
set autoscale y
set style fill   solid 0.5 border lt -1

##### End of GNUPLOT header #####
set ylabel "Aktivitáskoncentráció\nvízben [kBq/m^3]"
set xrange [-4.5:206]
set ytics
set output filename.'CW_DIST-'.COMP_NUM.'-'.BED_TYPE.'-Kdss_'.KD_ss.'-Kdbs_'.KD_bs.'-SED_'.SEDIM.SRC_STR.'.png'
set yrange [*:*]
set style fill solid 0.75 border lt -1

## BEGIN MULTIPLOT ##
set multiplot  title '[^{90}Sr]-['.COMP_NUM.'/'.BED_TYPE.']: K_d^{ss} = '\
			.KD_ss.'m^3kg^{-1}, K_d^{bb} = '.KD_bs.'m^3kg^{-1},  Ülepedés = '.SEDIM.', '.SRC_STR
set tmargin 2
set lmargin 11
set rmargin 1
set bmargin 1
unset xlabel
set format x ''
set bmargin at screen 0.30

	# Ábrázoljuk a hely szerinti eloszlást az 1996-os mért eredményekkel

plot SR_DISTANCE_CALC using 1:($2 + $3) w boxes title 'Oldott formában' lt -1 lc rgb 'blue', \
	 '' 			  using 1:3 w boxes title 'Lebegő részecskén adszorbeálva' lt -1  lc rgb 'cyan' , \
	 SR_DISTANCE_MEAS using 1:2:3 title 'Mért adatok (1996)' w errorbars lc rgb 'red' lw 2
unset bmargin
set tmargin at screen 0.275
set ylabel 'Üledékben [Bq/kg]'
set xlabel 'Távolság D11 -től [km]'
unset format x
set xtics mirror
set yrange [*:*] reverse
set key right bottom
plot SR_DISTANCE_CALC using 1:4 w boxes title 'Üledékben' lt -1 lc rgb 'brown' fill solid 0.25,\
     SR_DISTANCE_MEAS using 1:4:5 title 'Mért adatok (1996)' w errorbars lc rgb 'red' lw 2
unset multiplot
## END MULTIPLOT ##

unset tmargin
unset lmargin
unset rmargin
unset bmargin

set key right top
set output filename.'CW_TIME-'.COMP_NUM.'-'.BED_TYPE.'-Kdss_'.KD_ss.'-Kdbs_'.KD_bs.'-SED_'.SEDIM.SRC_STR.'-M.png'
set ylabel 'Aktivitáskoncentráció oldott és kötött formában [kBq/m^3]'
set xlabel 'Dátum [év]'
set style fill   solid 1 noborder
set xrange [1949:1996]
set yrange [0:30000]

	# Ábrázoljuk az időbeli lefolyást
set title '[^{90}Sr]-['.COMP_NUM.'/'.BED_TYPE.']:71 km D4 -től: K_d^{ss} = '\
			.KD_ss.' m^3kg^{-1}, K_d^b^b = '.KD_bs.' m^3kg^{-1},  Ülepedés = '.SEDIM.', '.SRC_STR
plot SR_TIMELINE_CALC using 1:($2 + $3) title 'Oldott formában' w boxes lc rgb 'blue' , \
		'' 			  using 1:3 title 'Lebegő részecskén adszorbeálva'	 w boxes lc rgb 'cyan',\
	 SR_TIMELINE_MEAS using 1:2 title 'Mért értékek: Muslyumovo' w lp lc rgb 'red' lw 1

set output filename.'CW_TIME-'.COMP_NUM.'-'.BED_TYPE.'-Kdss_'.KD_ss.'-Kdbs_'.KD_bs.'-SED_'.SEDIM.SRC_STR.'-P.png'
set ylabel 'Aktivitáskoncentráció oldott és kötött formában [kBq/m^3]'
set xlabel 'Dátum [év]'
set style fill   solid 1 noborder

set yrange [0:8200]
set title '[^{90}Sr]-['.COMP_NUM.'/'.BED_TYPE.']:205 km D4 -től: K_d^{ss} = '\
			.KD_ss.' m^3kg^{-1}, K_d^b^b = '.KD_bs.' m^3kg^{-1},  Ülepedés = '.SEDIM.', '.SRC_STR

plot SR_TIMELINE_CALC using 1:($4 + $5)		title 'Oldott formában' w boxes lc rgb 'blue' , \
		'' 			  using 1:5 title 'Lebegő részecskén adszorbeálva' w boxes lc rgb 'cyan',\
	 SR_TIMELINE_MEAS using 1:3 title 'Mért értékek: Pershino' w lp lc rgb 'red' lw 1

This snippet took 0.00 seconds to highlight.

Back to the Entry List or Home.

Delete this entry (admin only).