Demo entry 6796271

tst

   

Submitted by anonymous on May 14, 2019 at 04:39
Language: Java. Code size: 8.1 kB.

fini
/clear,start

/COM---------------------------------------------------------------------------------------------------------------
/COM Input file for the multi-mechanism continuum damage Model
/COM This is a Input File prepared for calculating the multi-mechanism continuum damage Model
/COM The specimen to be considered is cube sample with unit dimensions
/COM For P92 high-Cr steel at 873.15K, the TB, USER command is used to define 38 material parameters
/COM The TB, STATE command is used to define 31 state variables
/COM The element type is chosen as Solid185
/COM The cyclic loading loading test is considered
/COM Qingyang Huang, SCUT, 05.05.2019
/COM---------------------------------------------------------------------------------------------------------------


!********************************************************************************************************************
! the multi-mechanism damage Model
!********************************************************************************************************************

/FILNAME, Multiaxial_cyclic_test, Example 1.0
/TITLE, Multiaxial_cyclic_analysis

/UNITS, SI

! Used material parameters for material type one (P92 parent material)
Mat1 = 1

!---- Temperature: 600oC [K] ---------------------
Tem_600 = 873.15

!******************************************* Parameters in the model *******************************************
! -------------------material parameters--------------
! Creep strain parameter
n_c = 9.3
! initial yield stress, sigma_y
kk = 140.0
! Viscosity parameter, n_vp
n_p = 4.0
! Viscosity parameter, J
K = 3050.0
! modulus, E
EE = 1.676E5
! 2 * Shear modulus E/((1+nu)). Make it easy to construct the Residual equation, 2 * G = 2 * E/ (2 * (1+nu))
GG = 1.289e5
! Bulk modulus E/(3*(1-2*nu))
Mod_bulk = 1.3967E5
! a parameter in viscosity function, Alpha
con_a = 1.2E8
! Fatigue damage parameter
S_fn = 1.0
s_f = 3.2
! a threshold activates the fatigue damage
p_0 = 2.5
m_f = 20.0
! Creep damage parameter
S_cn = 11.9
s_c = 3.8
! ductile damage parameter
S_dn = 0.15
s_d = 4.0
m_d = 1.0
! a threshold activates the ductile damage epsilon_0
h_d = 8.6E-3

!----------------constant related to the Kinematic hardening----------------

! dynamic recovery in kinematic hardening variables
C_1 = 5.049E4
C_2 = 7.971E4
C_3 = 2.839E4
! dynamic recovery in kinematic hardening variables
gram_1 = 4.167E3
gram_2 = 1.707E3
gram_3 = 4.315E2
! Static recovery parameter in kinematic hardening
Ax_1 = 7.78E-3
Ax_2 = 7.78E-3
Ax_3 = 6.23E-2

!----------------- constant related to the Isotropic hardening----------------

! Related to the dynamic recovery effects of the isotropic hardening variables
Q = -165.0
bta = 1.8
! Static recovery parameter in isotropic hardening (neglected in this work, set to be 0)
A_R = 0.0
n_R = 0.0
! Creep strain paremeter
A_c = 3.548E-30
! Poisson's ratio
nu = 0.3

!----------------- Control Parameters---------------------------------------

! the variable indicate the solver. 1 for BiConjugate gradient solver (Faster), -1 for Pardiso solver (More Stable)
ind_solver = 1
! A threshold for checking convergence
eps = 1.0E-8
! maximum iteration steps in Newton iteration algorithm 
Num_It = 100
! maximum iteration steps in BiConjugate gradient solver
Num_It_bi = 100
! small tolerance values to control the BiConjugate gradient iteration
tol_bi = 1.0E-10

!******************************************* End of the Parameters*******************************************


!-------------------------------------------------------------------------
! Enter the preprocessor
!-------------------------------------------------------------------------
/PREP7

! Assign the material constants for Mat1 at different temperatures

!MPTEMP, 1, Tem_600
!MPDATA, DENS, Mat1, 1, c_Den

! Specify the reference temperature
TREF, 873.15

! Declare the material parameters for TB_USER material
TB, USER, Mat1, 1, 38 
TBTEMP, Tem_600
TBDATA, 1, n_c, kk, n_p, K, EE, GG 
TBDATA, 7, Mod_bulk, con_a, S_fn, s_f, p_0, m_f
TBDATA, 13, S_cn, s_c, S_dn, s_d, m_d, h_d
TBDATA, 19, C_1, C_2, C_3, gram_1, gram_2, gram_3
TBDATA, 25, Ax_1, Ax_2, Ax_3, Q, bta, A_R
TBDATA, 31, n_R, A_c, nu
TBDATA, 34, ind_solver, eps, Num_It, Num_It_bi, tol_bi

! Declare the state variables for TB_USER material
TB, STATE, Mat1, , 31


!---- Construct the Geometry of the Specimen-------------------------------!

! Construct the Cylinder
length = 2                 
inner_R = 0.3
outer_R = 0.5
CYLIND, inner_R, outer_R, 0, length, 0, 90
CYLIND, inner_R, outer_R, 0, length, 90, 180
CYLIND, inner_R, outer_R, 0, length, 180, 270
CYLIND, inner_R, outer_R, 0, length, 270, 360
VGLUE, ALL
ALLSEL

!---- Mesh of the component -------------------------------------------------!

ET,1,SOLID185
!KEYOPT, 1, 2, 2
LESIZE, 6, , , 3
LESIZE, 5, , , 7
LESIZE, 51, , , 7
LESIZE, 55, , , 7
LESIZE, 59, , , 7
LESIZE, 9, , , 20
ESIZE, 0.08
TYPE, 1
VMESH, ALL
ALLSEL

FINISH

!-------------------------------------------------------------------------
! Enter the solution
!------------------------------------------------------------------------
/SOLU
ANTYPE, STATIC
! ANTYPE, TRANS
! TRNOPT, FULL

!---- Mechanical boundary condition ---------------------------------!

!----------------------------Trianglr Positive---------------------
*SET,_FNCNAME,'DISPP' 
*SET,_FNCCSYS,0 
! /INPUT,1.func,,,1 
*DIM,%_FNCNAME%,TABLE,6,20,1,,,,%_FNCCSYS%  
!   
! Begin of equation: 0.01*(asin(abs(sin(PI/20*{TIME}+PI/4)))/(PI/4)-1)  
*SET,%_FNCNAME%(0,0,1), 0.0, -999   
*SET,%_FNCNAME%(2,0,1), 0.0 
*SET,%_FNCNAME%(3,0,1), 0.0 
*SET,%_FNCNAME%(4,0,1), 0.0 
*SET,%_FNCNAME%(5,0,1), 0.0 
*SET,%_FNCNAME%(6,0,1), 0.0 
*SET,%_FNCNAME%(0,1,1), 1.0, -1, 0, 3.14159265358979310, 0, 0, 0
*SET,%_FNCNAME%(0,2,1), 0.0, -2, 0, 20, 0, 0, -1
*SET,%_FNCNAME%(0,3,1),   0, -3, 0, 1, -1, 4, -2
*SET,%_FNCNAME%(0,4,1), 0.0, -1, 0, 1, -3, 3, 1 
*SET,%_FNCNAME%(0,5,1), 0.0, -2, 0, 3.14159265358979310, 0, 0, 0
*SET,%_FNCNAME%(0,6,1), 0.0, -3, 0, 4, 0, 0, -2 
*SET,%_FNCNAME%(0,7,1), 0.0, -4, 0, 1, -2, 4, -3
*SET,%_FNCNAME%(0,8,1), 0.0, -2, 0, 1, -1, 1, -4
*SET,%_FNCNAME%(0,9,1), 0.0, -1, 9, 1, -2, 0, 0 
*SET,%_FNCNAME%(0,10,1), 0.0, -1, 15, 1, -1, 0, 0   
*SET,%_FNCNAME%(0,11,1), 0.0, -1, 12, 1, -1, 0, 0   
*SET,%_FNCNAME%(0,12,1), 0.0, -2, 0, 3.14159265358979310, 0, 0, 0   
*SET,%_FNCNAME%(0,13,1), 0.0, -3, 0, 4, 0, 0, -2
*SET,%_FNCNAME%(0,14,1), 0.0, -4, 0, 1, -2, 4, -3   
*SET,%_FNCNAME%(0,15,1), 0.0, -2, 0, 1, -1, 4, -4   
*SET,%_FNCNAME%(0,16,1), 0.0, -1, 0, 1, 0, 0, -2
*SET,%_FNCNAME%(0,17,1), 0.0, -3, 0, 1, -2, 2, -1   
*SET,%_FNCNAME%(0,18,1), 0.0, -1, 0, 0.01, 0, 0, -3 
*SET,%_FNCNAME%(0,19,1), 0.0, -2, 0, 1, -1, 3, -3   
*SET,%_FNCNAME%(0,20,1), 0.0, 99, 0, 1, -2, 0, 0
! End of equation: 0.01*(asin(abs(sin(PI/20*{TIME}+PI/4)))/(PI/4)-1)
!-->


!---- Displacement restrictions on the boundary -------------
CSYS,1                      ! use the cylindrial coordinate system
NSEL, S, LOC, Z, 0	      ! select the nodes on the bottom side Z = 0 of the cylinder
D,ALL,UX,0                ! fixed bonudary condition
D,ALL,UY,0      
D,ALL,UZ,0      

NSEL, S, LOC, Z, length	 ! select the nodes on the top side Z = 2 of the cylinder
D,ALL,UX,0                ! fixed bonudary condition on two directions
D,ALL,UY,0      

! APPLY TABULAR displacement LOADS
D,ALL,UZ,%DISPP%
ALLSEL

! Internal pressure
SFA,32,1,PRES,30
SFA,36,1,PRES,30
SFA,28,1,PRES,30
SFA,4,1,PRES,30
ALLSEL
! Specify the convergennce criteria
! CNVTOL,F,,0.000001,2,1.0E-2
! CNVTOL,U,,0.0000001,0,1.0E-6


! Set the timestep issue
TIME, 260
DELTIM, 0.01
KBC, 1

OUTRES, ERASE
OUTRES, ALL, 10
OUTRES, SVAR, 10

NROPT, UNSYM
EQSLV, SPARSE

! Solve the problem
SOLVE

FINISH
!----------------------------------------------------------------------------------!

/POST1 
/VIEW, 1, -0.5 , -0.5 , 0.7
/ANG, 1, 1.0
/REPLO 
PLNSOL, S,EQV, 0,1.0

FINISH 
SAVE

This snippet took 0.03 seconds to highlight.

Back to the Entry List or Home.

Delete this entry (admin only).